{
  lib,
  stdenv,
  fetchurl,
}:

let
  version = "0.10.1";

  sources = {
    x86_64-linux = {
      url = "https://dl.gitea.com/tea/${version}/tea-${version}-linux-amd64";
      sha256 = "sha256-QcODwFm2T8hVCqBkp8FAnQ3KbNw8P0ZHv0iJ4zSP5mA=";
    };
    aarch64-linux = {
      url = "https://dl.gitea.com/tea/${version}/tea-${version}-linux-arm64";
      sha256 = "sha256-qfvJ4FJSHt1+sMG4hPwGNFLChqhNNf+l3ELQ97zZm50=";
    };
    x86_64-darwin = {
      url = "https://dl.gitea.com/tea/${version}/tea-${version}-darwin-amd64";
      sha256 = "sha256-WKjZKhFKWjZqnrdxPv00fzTIc0z4xrLSsL+jqLQ1huc=";
    };
    aarch64-darwin = {
      url = "https://dl.gitea.com/tea/${version}/tea-${version}-darwin-arm64";
      sha256 = "sha256-SMwxMEDKmhbLvLn1ZR1MmbjutZPk0P9QAfvNKCvrSk0=";
    };
  };

  src = sources.${stdenv.hostPlatform.system} or (throw "Unsupported system: ${stdenv.hostPlatform.system}");
in
stdenv.mkDerivation {
  pname = "tea";
  inherit version;

  src = fetchurl {
    inherit (src) url sha256;
  };

  dontUnpack = true;

  installPhase = ''
    runHook preInstall
    install -D $src $out/bin/tea
    runHook postInstall
  '';

  meta = with lib; {
    description = "A command line tool to interact with Gitea servers";
    homepage = "https://gitea.com/gitea/tea";
    license = licenses.mit;
    platforms = builtins.attrNames sources;
  };
}